@ECHO OFF
CLS
ECHO ...

REM we call AUTORUN.BAT and expect it to do initialization
REM e.g. set cdrom, LANG, and PATH

REM re-entry point for returning to menu.
for %%x in ( viewinstall makebf done begin initfdos ) do IF [%1]==[%%x] goto %1

:BEGIN
%cdrom%\FreeDOS\AUTORUN\autorun.bat
goto done

:initfdos
%cdrom%
CD \
CD FREEDOS
CD INSTALL

if [%CLI_END%]==[yes] goto done
REM set LANG to one of the at least partially supported
REM languages (during installation only)
CLS
TYPE %cdrom%\FREEDOS\INSTALL\DOCS\INSTLANG.TXT
CHOICE /C:012 "              "
set LANG=EN
IF ERRORLEVEL 2 set LANG=ES
IF ERRORLEVEL 3 set LANG=NL
CLS

REM Config Options 0,1,2,3 ; show BETA?.txt ; perform selected install; end in INST part.
for %%x in ( %cdrom%\FREEDOS\INSTALL\DOCS\%LANG%\BETA*.TXT ) DO TYPE %%x 
PAUSE
REM pg %cdrom%\FREEDOS\DOCS\README.TXT
REM pg %cdrom%\FREEDOS\DOCS\COPYING.TXT

REM Force user to read the INSTALLATION text, yes its kinda
REM annoying for those who know what they are doing, but its the only
REM way to get some people to at least glance at it.
IF EXIST %cdrom%\FREEDOS\INSTALL\DOCS\%LANG%\INST.TXT pg %cdrom%\FREEDOS\INSTALL\DOCS\%LANG%\INST.TXT
IF NOT EXIST %cdrom%\FREEDOS\INSTALL\DOCS\%LANG%\INST.TXT IF EXIST %cdrom%\FREEDOS\INSTALL\DOCS\EN\INST.TXT pg %cdrom%\FREEDOS\INSTALL\DOCS\EN\INST.TXT

REM Perform installation
CALL INST.BAT
if [%CLI_END%]==[yes] goto done
ECHO ...
set temp=a:\
set tmp=a:\
REM set path=a:;%path%
c:
for %%x in ( C: c: ) do if [%cdrom%]==[%%x] goto done
call %cdrom%\FREEDOS\INSTALL\director.bat
ECHO Installation complete.
GOTO done

:makebf
CLS
echo Creating generic CD boot disk.
echo Please insert a floppy into floppy drive.
echo When asked for a target (drive to write to), please specify
echo ÿ  If you are booting from the CD use B: for your 1st floppy drive
echo ÿ  otherwise use normal drive letters (i.e. A: for 1st floppy drive)
REM %cdrom%\FREEDOS\EXTRAS\RAWRITE\RAWRITE\RAWRITE2.EXE -f %cdrom%\FREEDOS\INSTALL\BOOTDISK\FDCD_144.DSK
%cdrom%\FREEDOS\EXTRAS\RAWRITE\FDIMAGE\FDIMAGE.EXE -s -v -f 1.44M %cdrom%\FREEDOS\INSTALL\BOOTDISK\FDCD_144.DSK B:
echo.
echo Copy your CD-ROM driver to the boot disk and reboot!
echo You can find a generic standard ATAPI/IDE/UDMA cdrom driver such as
echo Acer/Benq VIDE-CDD.SYS cdrom-driver and many other manufacturer's drivers
echo from:  http://digilander.libero.it/pnavato/drivers/
echo for example see http://www.benq.com/drivers/storage_drivers.html ("DOS Driver")
echo [ A CD-ROM Driver is presently NOT provided as they are copyrighted
echo   and none found so far explicitly allow for redistribution.        ]
pause
GOTO BEGIN

:viewinstall
pg %cdrom%\FREEDOS\DOCS\INSTALL3.TXT
GOTO BEGIN

:done
%cdrom%
CD \
call %cdrom%\freedos\install\END.BAT